Add metabuli/build module

modules/nf-core/metabuli/build/environment.yml

@@ -0,0 +1,7 @@
+---
+# yaml-language-server: $schema=https://raw.githubusercontent.com/nf-core/modules/master/modules/environment-schema.json
+channels:
+  - conda-forge
+  - bioconda
+dependencies:
+  - "bioconda::metabuli=1.1.1"

modules/nf-core/metabuli/build/main.nf

@@ -0,0 +1,58 @@
+process METABULI_BUILD {
+    tag "$meta.id"
+    label 'process_medium'
+    conda "${moduleDir}/environment.yml"
+    container "${ workflow.containerEngine == 'singularity' && !task.ext.singularity_pull_docker_container ?
+        'https://depot.galaxyproject.org/singularity/metabuli:1.1.1--pl5321h0bb26bb_0':
+        'biocontainers/metabuli:1.1.1--pl5321h0bb26bb_0' }"
+
+    input:
+    tuple val(meta), path(fasta)
+    path taxonomy_names, stageAs: 'taxonomy/names.dmp'
+    path taxonomy_nodes, stageAs: 'taxonomy/nodes.dmp'
+    path taxonomy_merged, stageAs: 'taxonomy/merged.dmp'
+    path accession2taxid, stageAs: 'taxonomy/*'
+    path cds_info
+
+    output:
+    tuple val(meta), path("$prefix"), emit: db
+    tuple val("${task.process}"), val('metabuli'), eval('metabuli 2>&1 | awk \'/metabuli Version:/ {print $3}\''), emit: versions_metabuli, topic: versions
+
+    when:
+    task.ext.when == null || task.ext.when
+
+    script:
+    def args = task.ext.args ?: ''
+    prefix = task.ext.prefix ?: "${meta.id}"
+    make_merged = taxonomy_merged ? "" : "touch taxonomy/merged.dmp"
+    cds_info_arg = cds_info ? "--cds-info cds_info.txt" : ""
+    """
+    $make_merged
+    echo $fasta | tr ' ' '\\n' > fasta.txt
+    echo $cds_info | tr ' ' '\\n' > cds_info.txt
+
+    metabuli build \\
+        "${prefix}" \\
+        fasta.txt \\
+        $accession2taxid \\
+        --taxonomy-path taxonomy \\
+        --max-ram ${task.memory.toGiga()} \\
+        --threads ${task.cpus} \\
+        ${cds_info_arg} \\
+        $args
+    """
+
+    stub:
+    def args = task.ext.args ?: ''
+    prefix = task.ext.prefix ?: "${meta.id}"
+    """
+    mkdir -p "$prefix"
+
+    touch "$prefix/acc2taxid.map"
+    touch "$prefix/diffIdx"
+    touch "$prefix/info"
+    touch "$prefix/split"
+    touch "$prefix/taxID_list"
+    touch "$prefix/db.parameters"
+    """
+}

modules/nf-core/metabuli/build/meta.yml

@@ -0,0 +1,88 @@
+name: "metabuli_build"
+description: Builds a database for classification with metabuli from FASTA files
+  and a taxonomy
+keywords:
+  - database
+  - taxonomic classification
+  - classification
+  - metagenomics
+tools:
+  - "metabuli":
+      description: "Metabuli: specific and sensitive metagenomic classification via
+        joint analysis of DNA and amino acid"
+      homepage: "https://github.com/steineggerlab/Metabuli"
+      documentation: "https://github.com/steineggerlab/Metabuli"
+      tool_dev_url: "https://github.com/steineggerlab/Metabuli"
+      doi: "10.1101/2023.05.31.543018"
+      licence:
+        - "GPL v3"
+      identifier: biotools:metabuli
+input:
+  - - meta:
+        type: map
+        description: |
+          Groovy Map containing sample information
+    - fasta:
+        type: file
+        description: List of fasta files with input assemblies
+        ontologies: []
+  - taxonomy_names:
+      type: file
+      description: File describing individual members of a taxonomic tree in NCBI
+        nodes.dmp format
+      ontologies: []
+  - taxonomy_nodes:
+      type: file
+      description: File describing parent-child relationships of a taxonomic tree
+        in NCBI nodes.dmp format
+      ontologies: []
+  - taxonomy_merged:
+      type: file
+      description: Optional input to map old/deprecated TaxID to new ones
+      ontologies: []
+  - accession2taxid:
+      type: directory
+      description: TSV file (with no header) of first column with mapping
+        accession (from first part of each fasta entry) and second column the
+        corresponding TaxID
+  - cds_info:
+      type: file
+      description: List of files to cds files
+      ontologies: []
+output:
+  db:
+    - - meta:
+          type: map
+          description: Groovy Map containing sample information
+      - $prefix:
+          type: directory
+          description: metabuli database directory for classification
+  versions_metabuli:
+    - - ${task.process}:
+          type: string
+          description: The name of the process
+      - metabuli:
+          type: string
+          description: The name of the tool
+      - metabuli 2>&1 | awk '/metabuli Version:/ {print $3}':
+          type: eval
+          description: The expression to obtain the version of the tool
+topics:
+  versions:
+    - - ${task.process}:
+          type: string
+          description: The name of the process
+      - metabuli:
+          type: string
+          description: The name of the tool
+      - metabuli 2>&1 | awk '/metabuli Version:/ {print $3}':
+          type: eval
+          description: The expression to obtain the version of the tool
+authors:
+  - "@pawelciurkaardigen"
+  - "@MichalStachowiakArdigen"
+  - "@sofstam"
+maintainers:
+  - "@pawelciurkaardigen"
+  - "@MichalStachowiakArdigen"
+  - "@softam"

modules/nf-core/metabuli/build/tests/main.nf.test

@@ -0,0 +1,171 @@
+nextflow_process {
+
+    name "Test Process METABULI_BUILD"
+    script "../main.nf"
+    process "METABULI_BUILD"
+
+    tag "modules"
+    tag "modules_nfcore"
+    tag "metabuli"
+    tag "metabuli/build"
+
+    test("sarscov2 - sarscov2 DNA - no cds info") {
+
+        when {
+            process {
+                """
+                input[0] = [
+                    [ id:'test' ],
+                        [
+                            file(params.modules_testdata_base_path + "genomics/sarscov2/genome/genome.fasta", checkIfExists: true),
+                        ]
+                    ]
+                input[1] = file(params.modules_testdata_base_path +'genomics/prokaryotes/metagenome/taxonomy/taxdmp/names.dmp', checkIfExists: true)
+                input[2] = file(params.modules_testdata_base_path +'genomics/prokaryotes/metagenome/taxonomy/taxdmp/nodes.dmp', checkIfExists: true)
+                input[3] = []
+                input[4] = file(params.modules_testdata_base_path + 'genomics/prokaryotes/metagenome/taxonomy/accession2taxid/nucl_gb.accession2taxid', checkIfExists: true)
+                input[5] = []
+                """
+            }
+        }
+
+        then {
+            assertAll(
+                { assert process.success },
+                { assert snapshot(
+                        path("${process.out.db[0][1]}/acc2taxid.map"),
+                        path("${process.out.db[0][1]}/diffIdx"),
+                        path("${process.out.db[0][1]}/info"),
+                        file("${process.out.db[0][1]}/split").name,
+                        path("${process.out.db[0][1]}/taxID_list"),
+                        file("${process.out.db[0][1]}/db.parameters").name,
+                        process.out.findAll { key, val -> key.startsWith("versions")}
+                        ).match()
+                }
+            )
+        }
+    }
+
+    test("sarscov2 - sarscov2 DNA - two input fasta") {
+
+        when {
+            process {
+                """
+                input[0] = [
+                    [ id:'test' ],
+                        [
+                            file(params.modules_testdata_base_path + "genomics/sarscov2/genome/genome.fasta", checkIfExists: true),
+                            file(params.modules_testdata_base_path + "genomics/prokaryotes/haemophilus_influenzae/genome/genome.fna.gz", checkIfExists: true),
+                        ]
+                    ]
+                input[1] = file(params.modules_testdata_base_path +'genomics/prokaryotes/metagenome/taxonomy/taxdmp/names.dmp', checkIfExists: true)
+                input[2] = file(params.modules_testdata_base_path +'genomics/prokaryotes/metagenome/taxonomy/taxdmp/nodes.dmp', checkIfExists: true)
+                input[3] = []
+                input[4] = file(params.modules_testdata_base_path + 'genomics/prokaryotes/metagenome/taxonomy/accession2taxid/nucl_gb.accession2taxid', checkIfExists: true)
+                input[5] = []
+                """
+            }
+        }
+
+        then {
+            assertAll(
+                { assert process.success },
+                { assert snapshot(
+                        path("${process.out.db[0][1]}/acc2taxid.map"),
+                        path("${process.out.db[0][1]}/diffIdx"),
+                        path("${process.out.db[0][1]}/info"),
+                        file("${process.out.db[0][1]}/split").name,
+                        path("${process.out.db[0][1]}/taxID_list"),
+                        file("${process.out.db[0][1]}/db.parameters").name,
+                        process.out.findAll { key, val -> key.startsWith("versions")}
+                        ).match()
+                }
+            )
+        }
+
+    }
+
+    test("sarscov2 - sarscov2 DNA - with cds info") {
+
+        when {
+            process {
+                """
+                input[0] = [
+                    [ id:'test' ],
+                        [
+                            file(params.modules_testdata_base_path + "genomics/sarscov2/genome/genome.fasta", checkIfExists: true),
+                        ]
+                    ]
+                input[1] = file(params.modules_testdata_base_path +'genomics/prokaryotes/metagenome/taxonomy/taxdmp/names.dmp', checkIfExists: true)
+                input[2] = file(params.modules_testdata_base_path +'genomics/prokaryotes/metagenome/taxonomy/taxdmp/nodes.dmp', checkIfExists: true)
+                input[3] = []
+                input[4] = file(params.modules_testdata_base_path + 'genomics/prokaryotes/metagenome/taxonomy/accession2taxid/nucl_gb.accession2taxid', checkIfExists: true)
+                input[5] = [
+                    file(params.modules_testdata_base_path + 'genomics/prokaryotes/bacteroides_fragilis/genome/genome.fna.gz', checkIfExists: true)
+                ]
+                """
+            }
+        }
+
+        then {
+            assertAll(
+                { assert process.success },
+                { assert snapshot(
+                        path("${process.out.db[0][1]}/acc2taxid.map"),
+                        path("${process.out.db[0][1]}/diffIdx"),
+                        path("${process.out.db[0][1]}/info"),
+                        file("${process.out.db[0][1]}/split").name,
+                        path("${process.out.db[0][1]}/taxID_list"),
+                        file("${process.out.db[0][1]}/db.parameters").name,
+                        process.out.findAll { key, val -> key.startsWith("versions")}
+                        ).match()
+                }
+            )
+        }
+
+    }
+
+    test("sarscov2 - sarscov2 DNA - with cds info - stub") {
+
+        options "-stub"
+
+        when {
+            process {
+                """
+                input[0] = [
+                    [ id:'test' ],
+                        [
+                            file(params.modules_testdata_base_path + "genomics/sarscov2/genome/genome.fasta", checkIfExists: true),
+                        ]
+                    ]
+                input[1] = file(params.modules_testdata_base_path +'genomics/prokaryotes/metagenome/taxonomy/taxdmp/names.dmp', checkIfExists: true)
+                input[2] = file(params.modules_testdata_base_path +'genomics/prokaryotes/metagenome/taxonomy/taxdmp/nodes.dmp', checkIfExists: true)
+                input[3] = []
+                input[4] = file(params.modules_testdata_base_path + 'genomics/prokaryotes/metagenome/taxonomy/accession2taxid/nucl_gb.accession2taxid', checkIfExists: true)
+                input[5] = [
+                    file(params.modules_testdata_base_path + 'genomics/prokaryotes/bacteroides_fragilis/genome/genome.fna.gz', checkIfExists: true)
+                ]
+                """
+            }
+        }
+
+        then {
+            assertAll(
+                { assert process.success },
+                { assert snapshot(
+                        path("${process.out.db[0][1]}/acc2taxid.map"),
+                        path("${process.out.db[0][1]}/diffIdx"),
+                        path("${process.out.db[0][1]}/info"),
+                        file("${process.out.db[0][1]}/split").name,
+                        path("${process.out.db[0][1]}/taxID_list"),
+                        file("${process.out.db[0][1]}/db.parameters").name,
+                        process.out.versions_metabuli
+                        ).match()
+                }
+            )
+        }
+
+    }
+
+
+}