sumup-java/src/build.gradle at 699464bc1d988d8ce2ddb42230c1d5e9749eadcd · sumup/sumup-java · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
import org.gradle.language.jvm.tasks.ProcessResources

plugins {
    id 'java-library'
    id 'com.diffplug.spotless'
    id 'maven-publish'
    id 'signing'
    id 'cl.franciscosolis.sonatype-central-upload' version '1.0.3'
}

base {
    archivesName = 'sumup-sdk'
}

java {
    withSourcesJar()
    withJavadocJar()
}

sourceSets {
    def emptyDirs = []
    main {
        java.srcDirs = ['main/java']
        resources.srcDirs = ['main/resources']
    }
    test {
        java.srcDirs = ['test/java']
        resources.srcDirs = emptyDirs
    }
}

dependencies {
    api 'com.fasterxml.jackson.core:jackson-annotations:2.21'
    api 'com.fasterxml.jackson.core:jackson-core:2.21'
    api 'com.fasterxml.jackson.core:jackson-databind:2.21'
    api 'com.fasterxml.jackson.datatype:jackson-datatype-jsr310:2.21.0'

    testImplementation 'org.junit.jupiter:junit-jupiter:5.10.2'
}

tasks.named('processResources', ProcessResources) {
    from(rootProject.file('VERSION')) {
        into('com/sumup/sdk')
        rename { 'sdk-version.txt' }
    }
}

tasks.withType(Javadoc).configureEach {
    options.addBooleanOption('Xdoclint:none', true)
    options.quiet()
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            artifactId = 'sumup-sdk'
            from components.java

            pom {
                name.set('SumUp Java SDK')
                description.set('Java SDK for the SumUp API.')
                url.set('https://github.com/sumup/sumup-java')

                licenses {
                    license {
                        name.set('Apache License, Version 2.0')
                        url.set('https://www.apache.org/licenses/LICENSE-2.0')
                    }
                }

                developers {
                    developer {
                        id.set('sumup')
                        name.set('SumUp')
                        email.set('opensource@sumup.com')
                        organization.set('SumUp')
                        organizationUrl.set('https://sumup.com')
                    }
                }

                scm {
                    url.set('https://github.com/sumup/sumup-java')
                    connection.set('scm:git:https://github.com/sumup/sumup-java.git')
                    developerConnection.set('scm:git:ssh://git@github.com/sumup/sumup-java.git')
                }
            }
        }
    }
}

sonatypeCentralUpload {
    username = System.getenv('SONATYPE_USERNAME')
    password = System.getenv('SONATYPE_PASSWORD')

    archives = files(
        "$buildDir/libs/sumup-sdk-${project.version}.jar",
        "$buildDir/libs/sumup-sdk-${project.version}-sources.jar",
        "$buildDir/libs/sumup-sdk-${project.version}-javadoc.jar"
    )

    pom = layout.buildDirectory.file("publications/mavenJava/pom-default.xml").get().asFile
    signingKey = System.getenv('SIGNING_KEY')
    signingKeyPassphrase = System.getenv('SIGNING_PASSWORD')
}

signing {
    def signingKey = System.getenv('SIGNING_KEY')
    def signingPassword = System.getenv('SIGNING_PASSWORD')
    if (signingKey && signingPassword) {
        useInMemoryPgpKeys(signingKey, signingPassword)
        sign(publishing.publications.mavenJava)
    }
}

tasks.named('sonatypeCentralUpload') {
    dependsOn(tasks.named('build'))
    dependsOn(tasks.named('generatePomFileForMavenJavaPublication'))
}