std/cmd.gs at main · goboscript/std · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
list cmd_args;

func cmd_next(start, cmd) {
    delete cmd_args;
    local key = "";
    local single_quote = false;
    local double_quote = false;
    local i = $start;
    until i > length($cmd) {
        if single_quote {
            if $cmd[i] == "'" and $cmd[i-1] != "\\" {
                single_quote = false;
                add key to cmd_args;
                key = "";
            }
            else {
                key &= $cmd[i];
            }
        }
        elif double_quote {
            if $cmd[i] == "\"" {
                double_quote = false;
                add key to cmd_args;
                key = "";
            }
            elif $cmd[i] == "\\" {
                i++;
                key &= $cmd[i];
            }
            else {
                key &= $cmd[i];
            }
        }
        elif $cmd[i] == "\"" {
            double_quote = true;
        }
        elif $cmd[i] == "'" {
            single_quote = true;
        }
        elif $cmd[i] == " " {
            if key != "" {
                add key to cmd_args;
                key = "";
            }
        }
        elif $cmd[i] == ";" {
            if key != "" {
                add key to cmd_args;
            }
            return i+1;
        }
        elif $cmd[i] == "\\" {
            i++;
            key &= $cmd[i];
        }
        else {
            key &= $cmd[i];
        }
        i++;
    }
    if key != "" {
        add key to cmd_args;
    }
    return 0;
}