android-mobilization/build.gradle.kts at d10837b725860c5f89a397b78ee2d01c9062ecc4 · elementsinteractive/android-mobilization · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
import io.gitlab.arturbosch.detekt.Detekt

// Top-level build file where you can add configuration options common to all sub-projects/modules.
buildscript {
    repositories {
        google()
        mavenCentral()
    }

    dependencies {
        classpath("com.android.tools.build:gradle:7.2.0")
        classpath("org.jetbrains.kotlin:kotlin-gradle-plugin:1.6.10")
        classpath("com.vanniktech:gradle-maven-publish-plugin:0.20.0")
    }
}

plugins {
    id("org.jetbrains.dokka") version "1.7.0"

    id("com.diffplug.spotless") version "6.12.0"
    id("io.gitlab.arturbosch.detekt") version "1.17.1"

    id("com.vanniktech.android.junit.jacoco") version "0.16.0"
    id("com.vanniktech.maven.publish") version "0.20.0" apply false
}

repositories {
    mavenCentral()
}

allprojects {
    repositories {
        google()
        mavenCentral()
        maven("https://maven.pkg.jetbrains.space/public/p/kotlinx-html/maven")
    }
}

subprojects {
    apply(plugin = "com.diffplug.spotless")
    spotless {
        kotlin {
            target("**/**.kt")

            ktlint(libs.versions.ktlint.get())

            licenseHeaderFile(rootProject.file("spotless/license.kt"))
        }
    }

    apply(plugin = "io.gitlab.arturbosch.detekt")
    detekt {
        input = files("$projectDir/src")
        config = files("$rootDir/detekt.yml")

        allRules = true
        buildUponDefaultConfig = true
        autoCorrect = false
    }
}

val detektCheck by tasks.registering(Detekt::class) {
    description = "Runs a failfast detekt build."
    parallel = true
    buildUponDefaultConfig = true

    setSource(files(
        "$projectDir/interactor/src",
        "$projectDir/logging-api/src",
        "$projectDir/logging/src"
    ))
    config.setFrom("$rootDir/detekt.yml")

    include("**/*.kt")
    include("**/*.kts")
    exclude(".*test.*")
    exclude("**/resources/**")
    exclude("**/tmp/**")
    exclude(".*/res/.*")
    exclude("**/build/**")
}

apply<nl.elements.mobilization.AndroidMetaModulePlugin>()
apply<nl.elements.mobilization.KotlinMetaModulePlugin>()
apply<nl.elements.mobilization.SigningMetaModulePlugin>()

apply(from = "gradle/jacoco.gradle")